	SUBROUTINE PARDEC(XMB,XMC,XMS,NCH,PHI,A)
	IMPLICIT REAL*8(A-H,O-Z)

C  CALCULATES PARTICLE DECAY ANGULAR DISTRIBUTION RESULTING FROM AN
C  INTERMEDIATE M-POPULATION
c Nov-2000 M.Yosoi   Rev. for IBM-xlf

	INCLUDE 'ANGCOR.INC'
	COMPLEX*16 A,C

	XMJ=XMB-XMC
	XML=XMJ-XMS
	ML=NINT(XML)
	A=(0.,0.)
	DO 1 I=1,NLDEC(NCH)
	IF(DELTA(NCH,I).EQ.0.) GO TO 1
	L=LDEC(NCH,I)
	XL=L
	XJ=FLOAT(JDEC(NCH,I))/2.
	IF (ABS(XMJ).GT.XJ.OR.ABS(XML).GT.XL) GO TO 1
	A=A+DELTA(NCH,I)*CG(XL,XML,XS,XMS,XJ,XMJ)*CG(XJ,XMJ,XJC,XMC,
     1    XJB(NCH),XMB)*C(L,ML,PHI)*SQRT(DFLOAT(2*L+1))/3.5449077

C  THE ABOVE NORMALIZATION ENSURES THAT THE INTEGRATED ANGULAR
C  DISTRIBUTION OVER THETA AND PHI IS UNITY.

1	CONTINUE
	RETURN
	END
